PFM: Cambiando la cámara en UDK a tercera persona

En el diseño del juego especificamos que la cámara será en tercera persona (se ve el personaje completo) pero por defecto, la cámara de UDK es subjetiva (vemos sólo los brazos del personaje y el arma que sujeta). En esta entrada veremos una manera de modificar la posición de la cámara para que sea en tercera persona.

Recomendable leer primero la introducción a UDK.

Nos basaremos en el ejemplo de cámara en tercera persona que hay en http://udn.epicgames.com/Three/CameraTechnicalGuide.html
pero simplificado, pues el ejemplo incluye código que no es necesario para obtener una cámara básica en tercera persona.

Antes de pasar al código necesario para conseguir la cámara conviene conocer 2 de las clases más importantes que habrá en el código de nuestro juego: Pawn y PlayerController.

• PlayerController es la clase responsable de transladar las acciones del jugador en acciones dentro del juego, ya sea mover su personaje, la cámara, o activar cualquier botón.
• Pawn es la clase que representa una entidad en el juego. Como su nombre indica (peón, títere) durante la partida será el avatar del jugador, el personaje que maneje. Las acciones del jugador serán traducidas por el PlayerController, que se encargará de mover el Pawn. El Pawn también se encarga de controlar la posición y rotación de la cámara.

Estas clases son vitales para cualquier juego que se desarrolle con UDK y un buen comienzo es crear nuestras propias versiones. Luego bastará con indicarle al GameType que utilice nuestras clases en vez de las que usa por defecto.

Igual que hicimos para crear un GameType propio, crearemos nuevas clases en la carpeta de código (en mi caso en Development\Src\PFM\Classes). Los nombres escogidos no importan, y al igual que con el GameType, nuestras clases extenderan de clases de UDK ya existentes para poder aprovechar su funcionalidad y extenderla o modificarla. Necesitamos estas 2 clases:

PFMPlayerController.uc

class PFMPlayerController extends UTPlayerController;

defaultproperties
{
}

La clase está vacía, pero la creamos igualmente.

PFMPawn.uc

class PFMPawn extends UTPawn;

// Sobreescribe una función para que se vea al pawn por defecto
// La llama la Camara cuando este actor se convierte en su ViewTarget
simulated event BecomeViewTarget( PlayerController PC )
{
    local UTPlayerController UTPC;

    // Por defecto esta llamada pone los brazos al Pawn y el arma inicial (y otras cosas)
    Super.BecomeViewTarget(PC);

    if (LocalPlayer(PC.Player) != None)
    {
        UTPC = UTPlayerController(PC);
        if (UTPC != None)
        {
            // Activa la vista trasera (Poner la camara en tercera persona y hace desaparecer brazos y armas de primera persona
            UTPC.SetBehindView(true);
            // Esto no es necesario
            //SetMeshVisibility(UTPC.bBehindView);
        }
    }
}

defaultproperties
{
    //Determina el 'zoom' de la cámara
    CameraScale=40.0

    // Se sobreescribe el valor del CamOffset por defecto CamOffset=(X=4.0,Y=16.0,Z=-13.0)
    CamOffset=(X=4.0,Y=0.0,Z=-13.0)
}

Básicamente en esta clase activamos la vista en tercera persona, hacemos visible el personaje del jugador y eliminamos el arma que se ve en primera persona. Además modificamos los parámetros CameraScale y CameraOffset para cambiar el Zoom y el desplazamiento de la cámara respectivamente.

Ahora bastaría con modificar la clase PFMGame que creamos aquí para indicarle que use nuestro Pawn y PlayerController:

class PFMGame extends UTDeathMatch;

defaultproperties
{
    //Se especifica el Pawn por defecto
    DefaultPawnClass=class'PFM.PFMPawn'
    //Se especifica el controlador
    PlayerControllerClass=class'PFM.PFMPlayerController'
}

Reiniciando el editor de UDK para que compile los scripts y seleccionando nuestro GameType en las WorldProperties ya podríamos ejecutar el mapa de prueba y ver el resultado: